📅 Jue, 30 Ene 2025 ⏲️ ~ 2 minutos Intermedio

Comunicación 1 a muchos con ESP-NOW en ESP32

En tutoriales anteriores, hemos cubierto los conceptos básicos de ESP-NOW, cómo configurar una comunicación 1 a 1 para enviar una variable simple, cómo enviar una estructura de datos (struct), un string, y un JSON.

En este tutorial, vamos a profundizar en el uso de ESP-NOW para implementar una comunicación 1 a muchos.

Para ello me voy a centrar en el ejemplo de enviar un string (por coger uno). Pero fácilmente podéis adaptarlo a enviar un struct, o Json, o lo que queráis.

En los próximos tutoriales, exploraremos cómo manejar una comunicación muchos a 1 y muchos a muchos.

¿Qué es una comunicación 1 a muchos?

En una comunicación 1 a muchos, un único dispositivo (emisor) envía datos a múltiples dispositivos (receptores).

esp32-espnow-one-to-many

Este tipo de comunicación es útil en aplicaciones donde un nodo central debe enviar comandos o configuraciones a varios nodos (como en sistemas de control de iluminación, redes de sensores, o sistemas de automatización)

La diferencia principal es que ahora, en lugar de tener una MAC de receptor, tenemos un array de MAC.

const uint8_t* RECEIVERS_MACS[] = { /* ... */ };
const uint8_t RECEIVERS_COUNT = sizeof(RECEIVERS_MACS) / sizeof(uint8_t*);

Y tenemos que registrarlas todas en el Emisor

void static RegisterPeek(uint8_t id)
{
	esp_now_peer_info_t peerInfo;
	memcpy(peerInfo.peer_addr, RECEIVERS_MACS[id], 6);
	peerInfo.channel = 0;
	peerInfo.encrypt = false;

	if(esp_now_add_peer(&peerInfo) != ESP_OK)
	{
		Serial.println("Failed to add peer");
	}
	else
	{
		Serial.print("Registered peer ");
		Serial.println(id);
	}
}

void static RegisterPeeks()
{
	for(auto peek_id = 0; peek_id < RECEIVERS_COUNT; peek_id ++)
	{
		RegisterPeek(peek_id);
	}
}

Por lo demás, básicamente es el mismo funcionamiento que habíamos visto.

Ejemplo completo

Vamos a ver el ejemplo completo 👇

Sender

Inicialización de ESP-NOW: Se inicializa ESP-NOW y se registra un callback para saber si el mensaje se envió correctamente.
Registro de peers: Se registran las direcciones MAC de los receptores como “peers” en la red ESP-NOW.
Envío del mensaje: Se envía un string a cada receptor utilizando esp_now_send. El string se convierte a un array de bytes utilizando payload.c_str().

#include <esp_now.h>
#include <WiFi.h>

#include "const.h"

void OnDataSent(const uint8_t* mac_addr, esp_now_send_status_t status)
{
	Serial.print("\r\nLast Packet Send Status:\t");
	Serial.println(status == ESP_NOW_SEND_SUCCESS ? "Delivery Success" : "Delivery Fail");
}

void SendMessage(uint8_t peek_id)
{
	String payload = "MY STRING";

	esp_err_t result = esp_now_send(RECEIVERS_MACS[peek_id], (uint8_t*)payload.c_str(), payload.length());

	if(result == ESP_OK)
	{
		Serial.println("Sent with success");
	}
	else
	{
		Serial.println("Error sending the data");
	}
}

void static RegisterPeek(uint8_t id)
{
	esp_now_peer_info_t peerInfo;
	memcpy(peerInfo.peer_addr, RECEIVERS_MACS[id], 6);
	peerInfo.channel = 0;
	peerInfo.encrypt = false;

	if(esp_now_add_peer(&peerInfo) != ESP_OK)
	{
		Serial.println("Failed to add peer");
	}
	else
	{
		Serial.print("Registered peer ");
		Serial.println(id);
	}
}

void static RegisterPeeks()
{
	for(auto peek_id = 0; peek_id < RECEIVERS_COUNT; peek_id ++)
	{
		RegisterPeek(peek_id);
	}
}

void static InitEspNow()
{
	if(esp_now_init() != ESP_OK)
	{
		Serial.println("Error initializing ESP-NOW");
	}
	else
	{
		esp_now_register_send_cb(OnDataSent);
		
		RegisterPeeks();
	}
}

void setup()
{
	Serial.begin(115200);
	delay(2000);
	WiFi.mode(WIFI_STA);

	InitEspNow();
}

void loop()
{
	SendMessage(0);

	delay(2000);
}

Receiver

#include <esp_now.h>
#include <WiFi.h>

#include "const.h"

void OnMessageReceived(const uint8_t* mac, const uint8_t* data, int len)
{
	Serial.printf("Packet received from: %02X:%02X:%02X:%02X:%02X:%02X\n", mac[0], mac[1], mac[2], mac[3], mac[4], mac[5]);
	Serial.printf("Bytes received: %d\n", len);

	String payload;
	payload.reserve(len);
	for(auto i = 0; i < len; i++)
	{
		payload += (char)data[i];
	}

	Serial.println(payload);
}

void InitEspNow()
{
	if(esp_now_init() != ESP_OK)
	{
		Serial.println("Error initializing ESP-NOW");
		return;
	}
	else
	{
		esp_now_register_recv_cb(OnMessageReceived);
	}
}

void setup()
{
	Serial.begin(115200);

	WiFi.mode(WIFI_STA);

	InitEspNow();
}

void loop()
{

}

Constants

const uint8_t MAC_SENDER_1[] = { 0x00, 0x00, 0x00, 0x00, 0x00, 0x00 };
const uint8_t MAC_RECEIVER_1[] = { 0x00, 0x00, 0x00, 0x00, 0x00, 0x00 };

const uint8_t* RECEIVERS_MACS[] = { MAC_RECEIVER_1 };
const uint8_t RECEIVERS_COUNT = sizeof(RECEIVERS_MACS) / sizeof(uint8_t*);