How to use MQTT on ESP8266/ESP32

Our main sketch is simple and easy to understand. There are some function calls defined in the files, which we will see next.

But, in summary, in the setup we initiate the WiFi and MQTT communication. On the other hand, in the ‘loop’, we manage the messages received by MQTT, while sending the value of ‘millis()‘. Simple.

#include <WiFi.h>
#include <SPIFFS.h>
#include <PubSubClient.h>

#include "config.h"  // Replace with your network data
#include "MQTT.hpp"
#include "ESP32_Utils.hpp"
#include "ESP32_Utils_MQTT.hpp"

void setup(void)
{
  Serial.begin(115200);
  SPIFFS.begin();

  ConnectWiFi_STA(true);

  InitMqtt();
}

void loop()
{
  HandleMqtt();

  PublisMqtt(millis());

  delay(1000);
}

On the other hand, the file “ESP32_Utils_MQTT.hpp” contains generic functions for MQTT communication. Like the other ‘Utils’ files we have used, it is intended to contain code that you can reuse between projects with little or no modification.

Here we have these functions for InitMqtt(), ConnectMqtt(), and HandleMqtt()

void InitMqtt() 
{
  mqttClient.setServer(MQTT_BROKER_ADRESS, MQTT_PORT);
  SuscribeMqtt();
  mqttClient.setCallback(OnMqttReceived);
}

void ConnectMqtt()
{
  while (!mqttClient.connected())
  {
    Serial.print("Starting MQTT connection...");
    if (mqttClient.connect(MQTT_CLIENT_NAME))
    {
      SuscribeMqtt();
    }
    else
    {
      Serial.print("Failed MQTT connection, rc=");
      Serial.print(mqttClient.state());
      Serial.println(" try again in 5 seconds");

      delay(5000);
    }
  }
}

void HandleMqtt()
{
  if (!mqttClient.connected())
  {
    ConnectMqtt();
  }
  mqttClient.loop();
}

Finally, in the ‘MQTT.hpp’ file we have defined the functions that are specific to your project. These functions are “the essence” of the project, and we will have to adapt them according to the characteristics of the project.

So, we have the definitions of the broker address, the port (default 1883 is fine), and the client name. Remember that two clients with the same name should not connect to the same broker.

On the other hand, we have the SuscribeMqtt function that subscribes the ESP8266/ESP32 to the topics we want to listen to. The PublisMqtt function sends a message via MQTT, in this case simply a long number. Finally, the OnMqttReceived function is executed when receiving a message via MQTT and, in this example, simply displays the content through the serial port.

const char* MQTT_BROKER_ADRESS = "192.168.1.150";
const uint16_t MQTT_PORT = 1883;
const char* MQTT_CLIENT_NAME = "ESP8266Client_1";

WiFiClient espClient;
PubSubClient mqttClient(espClient);

void SuscribeMqtt()
{
  mqttClient.subscribe("hello/world");
}

String payload;
void PublisMqtt(unsigned long data)
{
  payload = "";
  payload = String(data);
  mqttClient.publish("hello/world", (char*)payload.c_str());
}

String content = "";
void OnMqttReceived(char* topic, byte* payload, unsigned int length) 
{
  Serial.print("Received on ");
  Serial.print(topic);
  Serial.print(": ");

  content = "";  
  for (size_t i = 0; i < length; i++) {
    content.concat((char)payload[i]);
  }
  Serial.print(content);
  Serial.println();
}